Внутренняя ошибка динамического списка неожиданный тип макета области строк

&НаСервере
Процедура СозданиеДинамическогоСписка(
   ИмяДинамичСписка = «Список», // тип строка — имя будущего списка на форме и реквизита
   ТекстЗапроса = «»,  // тип строка — запрос, если он не указан, необходимо указать таблицу
   МассивКолонокДС,  // тип массив — массив создаваемых колонок, значения тип строка. Пример: «Д,ДоговораКонтрагента» значит будет создана колонка
// с заголовком «Д» и колонкой списка «ДоговораКонтрагента». Если указать просто «ДоговораКонтрагента»,
//  заголовок будет идентичен заголовку по умолчанию типа «Договор контрагента».
   СписокДействийДС = Неопределено,  // типа структура — структура содержит действия (свойства) динамического списка, можно указать только те которые необходимы.
// пример: СписокДействийДС = Новый Структура(«Выбор,ПриАктивизацииСтроки»,»СписокВыбор»,»СписокПриАктивизацииСтроки»)
   ТаблицаДинамичСписка = «», // тип строка — содержит имя основной таблицы, пример: «Документ.РеализацияТоваров»
   ДобавитьВ = «», // тип строка — имя элемента на который будет размещен список, если пустое, тогда добавляется на форму
   ВставитьПеред = «», // тип строка — имя элемента перед которым будет размещен список, если пустое, будет просто добавлен в конец
   СвояКоманднаяПанель = Ложь, // тип булево — если ИСТИНА, скрывает стандартную панель и создает свою пустую для будушего наполнения ИмяДинамичСписка+»КоманднаяПанель2″
   ПараметрыЗапроса = Неопределено) //тип структура — содержит перечень параметров, если они используются в запросе.

   //Защита от дурака
   Если ТекстЗапроса = «» И ТаблицаДинамичСписка = «» Тогда Сообщить(«Ошибка формирования динамического списка, укажите запрос или таблицу»); Возврат; КонецЕсли;

   //Создаем свою командную панель, тот случай когда я не нашел способа снять галочку «Автозаполнение»
   Если СвояКоманднаяПанель Тогда
       Если ВставитьПеред = «» Тогда
           ГруппаДинамическогоСписка  = Элементы.Добавить(«Группа» + ИмяДинамичСписка + «CоСвоейКоманднойПанелью»,Тип(«ГруппаФормы»),?(ДобавитьВ = «»,ЭтаФорма,ЭтаФорма.Элементы[ДобавитьВ]));
       Иначе
           ГруппаДинамическогоСписка  = Элементы.Вставить(«Группа» + ИмяДинамичСписка + «CоСвоейКоманднойПанелью»,Тип(«ГруппаФормы»),?(ДобавитьВ = «»,ЭтаФорма,ЭтаФорма.Элементы[ДобавитьВ]),ЭтаФорма.Элементы[ВставитьПеред]);
       КонецЕсли;
       ГруппаДинамическогоСписка.Вид = ВидГруппыФормы.ОбычнаяГруппа;
       ГруппаДинамическогоСписка.ОтображатьЗаголовок = Ложь;
       ГруппаДинамическогоСписка.Отображение = ОтображениеОбычнойГруппы.Нет;
       ГруппаДинамическогоСписка.Группировка = ГруппировкаПодчиненныхЭлементовФормы.Вертикальная;
       КоманднаяПанельСписка  = Элементы.Добавить(ИмяДинамичСписка + «КоманднаяПанель2»,Тип(«ГруппаФормы»),ГруппаДинамическогоСписка);
       КоманднаяПанельСписка.Вид = ВидГруппыФормы.КоманднаяПанель;
   КонецЕсли;

   //Создаем реквизит формы
   ТипыРеквизита = Новый Массив;
   ТипыРеквизита.Добавить(Тип(«ДинамическийСписок»));
   ОписаниеТиповДляРеквизита = Новый ОписаниеТипов(ТипыРеквизита);
   ДинамическийСписок = Новый РеквизитФормы(ИмяДинамичСписка, ОписаниеТиповДляРеквизита,,«»,Ложь); //Имя реквизита
   ДобавляемыеРеквизиты = Новый Массив;
   ДобавляемыеРеквизиты.Добавить(ДинамическийСписок);

   //Задаем свойства реквизиту
   ИзменитьРеквизиты(ДобавляемыеРеквизиты);
   РеквизитДинамическийСписок = ЭтаФорма[ИмяДинамичСписка]; //Имя реквизита
   Если ТекстЗапроса = «» Тогда
       РеквизитДинамическийСписок.ПроизвольныйЗапрос = Ложь;
       РеквизитДинамическийСписок.ОсновнаяТаблица = ТаблицаДинамичСписка;
   Иначе
       РеквизитДинамическийСписок.ПроизвольныйЗапрос = Истина;
       РеквизитДинамическийСписок.ТекстЗапроса = ТекстЗапроса;
       Если ТаблицаДинамичСписка <> «» Тогда РеквизитДинамическийСписок.ОсновнаяТаблица = ТаблицаДинамичСписка; КонецЕсли;
   КонецЕсли;

   //Заполняем параметры если они были указаны
   Если ПараметрыЗапроса <> Неопределено Тогда
       Для Каждого Параметра Из ПараметрыЗапроса Цикл
           РеквизитДинамическийСписок.Параметры.УстановитьЗначениеПараметра(Параметра.Ключ,Параметра.Значение);
       КонецЦикла;
   КонецЕсли;

   //Размещаем реквизит на форме
   Если Ложь
       Или ВставитьПеред = «»
       Или СвояКоманднаяПанель //Если своя командная панель тогда нет логики уже в параметре ВставитьПеред
       Тогда
       ТаблицаФормы = Элементы.Добавить(ИмяДинамичСписка,Тип(«ТаблицаФормы»),?(СвояКоманднаяПанель,ГруппаДинамическогоСписка,?(ДобавитьВ = «»,ЭтаФорма,ЭтаФорма.Элементы[ДобавитьВ])));
   Иначе
       ТаблицаФормы = Элементы.Вставить(ИмяДинамичСписка,Тип(«ТаблицаФормы»),?(ДобавитьВ = «»,ЭтаФорма,ЭтаФорма.Элементы[ДобавитьВ]),ЭтаФорма.Элементы[ВставитьПеред]);
   КонецЕсли;
   ТаблицаФормы.ПутьКДанным = ИмяДинамичСписка; //Имя реквизита

   //Если своя панель тогда скрываем стандартную
   Если СвояКоманднаяПанель Тогда
       Элементы[ИмяДинамичСписка].ПоложениеКоманднойПанели = ПоложениеКоманднойПанелиЭлементаФормы.Нет;
   КонецЕсли;

   //Создание колонок на основание МассивКолонокДС
   Для Каждого Элемента Из МассивКолонокДС Цикл
       ПараметрыКолонки = СтрЗаменить(Элемента,«,»,Символы.ПС);
       Если СтрЧислоСтрок(ПараметрыКолонки) > 1 Тогда
           Заголовок = СтрПолучитьСтроку(ПараметрыКолонки, 1);
           ИмяКолонки = СтрПолучитьСтроку(ПараметрыКолонки, 2);
       Иначе
           Заголовок = «»;
           ИмяКолонки = ПараметрыКолонки;
       КонецЕсли;
       НоваяКолонкаТаблицы = Элементы.Добавить(ИмяДинамичСписка + ИмяКолонки, Тип(«ПолеФормы»), ТаблицаФормы);
       Если Заголовок <> «» Тогда НоваяКолонкаТаблицы.Заголовок = Заголовок; КонецЕсли;
       НоваяКолонкаТаблицы.ПутьКДанным = ИмяДинамичСписка + «.» + ИмяКолонки;
   КонецЦикла;

   //Задаем действия (События) на основание СписокДействийДС, если он определен
   Если СписокДействийДС <> Неопределено Тогда
       ПереченьСвойств = «ПриИзменении
       |Выбор
       |ПриАктивизацииСтроки
       |ВыборЗначения
       |ПриАктивизацииПоля
       |ПриАктивизацииЯчейки
       |ПередНачаломДобавления
       |ПередНачаломИзменения
       |ПередУдалением
       |ПриНачалеРедактирования
       |ПередОкончаниемРедактирования
       |ПриОкончанииРедактирования
       |ОбработкаВыбора
       |ПередРазворачиванием
       |ПередСворачиванием
       |ПослеУдаления
       |ПриСменеТекущегоРодителя
       |ОбработкаЗаписиНового
       |ПриСохраненииПользовательскихНастроекНаСервере
       |ПередЗагрузкойПользовательскихНастроекНаСервере
       |ПриЗагрузкеПользовательскихНастроекНаСервере
       |ПриОбновленииСоставаПользовательскихНастроекНаСервере
       |ОбработкаЗапросаОбновления
       |ПриПолученииДанныхНаСервере
       |НачалоПеретаскивания
       |ПроверкаПеретаскивания
       |ОкончаниеПеретаскивания
       |Перетаскивание»;
       Для Счетчик = 1 По 28 Цикл
           ИмяСвойства = СтрПолучитьСтроку(ПереченьСвойств, Счетчик);
           Элементы[ИмяДинамичСписка].УстановитьДействие(ИмяСвойства,?(СписокДействийДС.Свойство(ИмяСвойства),СписокДействийДС[ИмяСвойства],«»));
       КонецЦикла;
   КонецЕсли;

КонецПроцедуры